Submission #24648

---

Source Code Expand

module main;

import std.stdio; // この解答で使った項目: readln
import std.conv; // この解答で使った項目: to
import std.string; // この解答で使った項目: strip
import std.math; // この解答で使った項目: sqrt

void main()
{
    auto n = readln().strip().to!int();
    int[] x;
    int[] y;
    // 最大距離の2乗
    ulong max_distance = 0;
    foreach (i; 0..n)
    {
        // std.array.split: 文字列を空白文字で区切る。
        // std.array は自動的に import され、準備なしに使うことができる。
        string[] point = readln().strip().split();
        x ~= point[0].to!int();
        y ~= point[1].to!int();
        debug
        {
            writefln("(%d, %d)", x[i], y[i]);
        }
        // 0..i とすれば、いま追加した点の他にわたってループできる。
        foreach (j; 0..i)
        {
            // 現在の距離の2乗。三平方の定理より。累乗には演算子 ^^ を使う。かわいい。
            ulong current_distance = (x[j] - x[i]) ^^ 2 + (y[j] - y[i]) ^^ 2;
            debug
            {
                writefln("(point[%d], point[%d]).dist = %d.sqrt", j, i, current_distance);
            }
            // もし今までの最大距離より大きければ更新する: 最大や最小をループで求める時の常套手段。
            if (max_distance < current_distance)
            {
                max_distance = current_distance;
            }
        }
    }
    // std.math.sqrt: 平方根を求める。
    // 浮動小数点に変換し、その平方根を求めて出力する。
    writefln("%f", sqrt(to!double(max_distance)));
}

// simple version: http://arc004.contest.atcoder.jp/submissions/24639

Submission Info

Judge Result